הפן הטכני קל איתי

[Og]

אני מניח שאתה מדבר על בעיית הצבעים הנודעת לשמצה של חלונות 7. יש כמה דרכים לסדר את זה אבל כולן כוללות משהו שצריך לעשות כל פעם לפני שאתה מפעיל את המשחק, אז אם הבעיה מפריעה לך תאמר לי ואפרט.

או שפשוט תפעיל את המשחק עם חבילת הDB+W95 שעלתה בשעה טובה:
viewtopic.php?f=2&t=21469" target="_blank
(ובאותה הזדמנות תיתן לי קצת פידבק עליה, אם יש לך)

אגב, הפעלתי את Hunter Hunted אצלי בחלונות 7, ואמנם התפריטים בחלון אבל המשחק עובד במסך מלא. אני די בטוח שזה לא היה ככה בXP בפעם האחרונה שבדקתי.

[brother34]

Hunter Hunted עובד אצלי במצב תאימות 640X480 במסך מלא כל הזמן, ובלי זה הוא עובד כל הזמן בחלון
(שאפשר להגדיל על כל המסך, אבל זה נראה קצת גדול מדי).
כל הזמן הכוונה בתפריטים ובמשחק עצמו.

[Gordi]

לא כל כך הבנתי מה אתה מנסה לעשות, אתה רוצה תוכנה שתבדוק אם יש קובץ GO.BAT ואם כן תפעיל אותו עם דוסבוקס? זה לא בדיוק מה שהחבילה המוכנה של דוסבוקס שנמצאת באתר כבר עושה ?

הרעיון הוא שאם אנחנו הולכים לכיוון של "דחיפה" אגרסיבית יותר של החבילה הזו, להמנע מהצורך לקבץ אותה עם עותק של DOSBox בכל הורדה.
אני מניח שגם הדיוטות יודעים להוריד התקנה ולסיים אותה בהצלחה כשהיא לא דורשת שום קלט מיוחד מהמשתמש (כלומר, זה תהליך של Next->Next->Next->Finish). מהרגע שהמשתמש התקין את DOSBox לפי ברירת המחדל, אנחנו יודעים היכן הנתיב של DOSBox.exe ויכולים לנסות לפנות אליו מרחוק, ללא הצורך לכלול אותו בתיקיית המשחק. ואם המשתמש שינה את נתיב ההתקנה, לדעתי הוא מבין מספיק בשביל להסתדר ללא חבילות אוטומטיות

אז השאלה שלי היא כזאת - האם זה נשמע לכם הגיוני? והאם במקרה כזה, יש יתרון כלשהו ב-Exe (מלבד היכולת לכתוב ל-Console בצבעים / לספק אייקון לתוכנה) או שעדיף ללכת על קובץ אצווה שימנע מכולם את התקף הלב ש-RG מתאר?

אגב, הפרופיל שלי מראה שנשארו לי 10 מגה מתוך 50...

הכפלתי, תודה שהבאת את זה לתשומת ליבי.

מה דעתך על זה:

נראה מעולה! תוכל בבקשה לשלוח לי?

בכיף, אני אשמח

אחלה, שמח לשמוע . אמרת גם משהו אחרי זה? לא הצלחתי לשמוע...

[Og]

הרעיון הוא שאם אנחנו הולכים לכיוון של "דחיפה" אגרסיבית יותר של החבילה הזו, להמנע מהצורך לקבץ אותה עם עותק של DOSBox בכל הורדה.

בכל הורדה? הורדה של מה? יש רק הורדה אחת והיא של החבילה...
או שאתה מתכוון בכל פעם שמישהו מוריד את החבילה? ז"א, השיקול היחיד שלך בעד השיטה הזו הוא רוחב פס?
לדעתי יש לגישה הזו כמה חסרונות, אבל אם רוחב הפס כזה משמועתי, אז אני מניח שזה לא נורא.

אז השאלה שלי היא כזאת - האם זה נשמע לכם הגיוני? והאם במקרה כזה, יש יתרון כלשהו ב-Exe (מלבד היכולת לכתוב ל-Console בצבעים / לספק אייקון לתוכנה) או שעדיף ללכת על קובץ אצווה שימנע מכולם את התקף הלב ש-RG מתאר?

אני בעד קובץ אצווה, אני לא יכול לחשוב אזשהו יתרון לEXE. אפשר לעשות משהו מאד בסיסי כמו:

קוד: בחירת הכל

:START
@echo off
REM Load Hebrew font:
fonthe.com > nul

:X86CHECK
if exist "%ProgramFiles%\DOSBox-0.74\dosbox.exe" goto X86RUN

:X64CHECK
if exist "%ProgramFiles(x86)%\DOSBox-0.74\dosbox.exe" goto X64RUN

:NODOSBOX
echo דוסבוקס לא נמצא בתיקיית ברירת המחדל או לא מותקן בכלל
goto EXIT

:X86RUN
start "%ProgramFiles%\DOSBox-0.74\dosbox.exe" go.bat
exit

:X64RUN
start "%ProgramFiles(x86)%\DOSBox-0.74\dosbox.exe" go.bat
exit

:EXIT

זה רק משהו שרשמתי עכשיו. לא בדקתי את זה וסביר להניח שיש טעויות תחביר ו/או טעויות לוגיות - זה לא משנה, זה נועד רק להמחיש את הנקודה.
כמובן שהפונט העברי לא יעבוד במערכות הפעלה בנות זמננו, כנראה שאין ברירה מלבד לכתוב באנגלית.
בנוסף, אם המשתמש שידרג את דוסבוקס לגרסה חדשה, הקובץ לא יעבוד.

נראה מעולה! תוכל בבקשה לשלוח לי?

http://server10.old-games.org/g/albums/ ... alogo4.zip

[Radioactive Grandpa]

סליחה שהתעוררתי רק עכשיו, אבל,

מה דעתך על זה:

נראה מעולה! תוכל בבקשה לשלוח לי?

וסליחה אם מה שאני אומר לא קשור (לא ראיתי את המקור), אבל מה רע באפשרות הזו?



ולמה הלוגו (על פי התמונה של עוג) שהוטבע שם היה בפורמט lossy?


בעניין ה"חבילה", נראה לי שאני כבר לא מצליח להבין מה קורה פה. מה שנראה שמתגבש כאן הוא בכלל לא "חבילה", אלא קובץ אצווה חדש שיחליף את ה-go.bat שקיים שם (או שיהיה לצידו) כחלק מההורדה הבסיסית.

[Og]

אבל מה רע באפשרות הזו?

אני לא רואה אפשרות כזו בWINRAR שלי, באיזו גרסה אתה משתמש?

ולמה הלוגו (על פי התמונה של עוג) שהוטבע שם היה בפורמט lossy?

זה מה שגורדי שלח לי בזמנו, אני משער שזה לא בפורמט LOSSY אלא זה פשוט מתוח (שים לב שהמידות שונות) ולכן יש איבוד איכות.

בעניין ה"חבילה", נראה לי שאני כבר לא מצליח להבין מה קורה פה. מה שנראה שמתגבש כאן הוא בכלל לא "חבילה", אלא קובץ אצווה חדש שיחליף את ה-go.bat שקיים שם (או שיהיה לצידו) כחלק מההורדה הבסיסית.

גם אני לא אוהב את הרעיון, אבל אף אחד מאיתנו לא יכול להיכנס לגורדי לכיס.

[Radioactive Grandpa]

אני לא רואה אפשרות כזו בWINRAR שלי, באיזו גרסה אתה משתמש?

Paint for Windows 7 version 6.1
(התנצלתי מראש אם אמרתי משהו לא קשור... חשבתי שזו תכנית קטנה שנבנתה לצורך העניין, לא שמדובר באפשרויות מובנות ב-WinRAR. עכשיו ראיתי במה מדובר.)

אני משער שזה לא בפורמט LOSSY אלא זה פשוט מתוח (שים לב שהמידות שונות) ולכן יש איבוד איכות.

לא נראה לי סביר. ההשחתה הזו לא דומה בכלל למתיחה.

אבל אף אחד מאיתנו לא יכול להיכנס לגורדי לכיס.

לכיס? אני מנסה להיכנס לראש.

[Og]

Paint for Windows 7 version 6.1
(התנצלתי מראש אם אמרתי משהו לא קשור... חשבתי שזו תכנית קטנה שנבנתה לצורך העניין, לא שמדובר באפשרויות מובנות ב-WinRAR. עכשיו ראיתי במה מדובר.)

אמרו חז"ל: "צרת רבים - חצי נחמה" אז אני לא מתבייש בזה שאני שמח לראות שאני לא היחיד שמזדקן.

לא נראה לי סביר. ההשחתה הזו לא דומה בכלל למתיחה.

אוקיי, אז תיאלץ לחכות לתשובה מגורדי.

לכיס? אני מנסה להיכנס לראש.

אני שוב אומר שלא בטוח שהבנתי את גורדי נכון, אבל אם כן, אז הראש חושב על הכיס, כלומר, הוא חושש שאם יהיה הטקסט באדום/ירוק שהצעת, תהיינה הרבה הורדות לחבילה הנ"ל (אולי הוא חושב שאנשים יורידו את החבילה בכל פעם שהם מורידים משחק במקום פעם אחת ואז להעתיק/לחלץ לתיקיית המשחק) מה שיגביר את השימוש ברוחב הפס משמעותית.

[Gordi]

אני אנסה להסביר את עצמי טוב יותר:

כיום אנחנו מציעים להורדה משחקים שונים. לאחר הורדת משחק כלשהו, אנחנו מפנים את המשתמש למדריך הדוסבוקס ("המדריך השלם"). שם, אנחנו מנסים להסביר כיצד להשתמש בדוסבוקס על מנת להפעיל משחקים ישנים. אולם, בהקדמה של אותו מדריך, אנחנו גם מציעים למשתמשים שלא רוצים להסתבך ("אם ברצונכם לנסות תחילה את הדרך הבסיסית והפשוטה ביותר...") את החבילה המוכנה שלנו, זאת שכוללת את דוסבוקס יחד עם קובץ אצווה בסיסי שמחפש את "Go.bat" ומפעיל אותו עם עותק הדוסבוקס המצורף. כלומר, לפי הפתרון הזה, על כל משחק שרוצים להפעיל יהיה עותק של דוסבוקס בתיקיית המשחק, אבל אין צורך להוריד בכל פעם את החבילה מחדש מכיוון שהחבילה לא מותאמת לאף משחק, מדובר בחבילה כללית שאנחנו מציעים ללא קשר למשחק שאותו רוצים להפעיל.

הקישור לחבילה הזו נמצא קצת "עמוק" בתוך האתר - הוא מקושר ממדריך שמקושר ממדריך שמקושר מהדף שאחרי הורדת משחקים. עלתה פה ההצעה לשווק את החבילה הזו באופן קצת יותר אגרסיבי - לקשר למדריך של החבילה ישירות מדף הורדת המשחק ולצד ההורדה עצמה. דבר זה יגדיל בוודאות את כמות ההורדות של החבילה, מה שאכן ישפיע על רוחב הפס של השרתים שלנו. מה גם שהפתרון הזה הוא רחוק מאידיאלי בכך שהוא מאלץ את המשתמש להחזיק בעותק של דוסבוקס על כל משחק, וזה בעייתי כפליים בעיני כאשר מדובר בפתרון ה"רשמי" של האתר (כלומר, זה שנדחף בצורה האגרסיבית ביותר).

אז חשבתי לעצמי: למה לא לשנות את החבילה למשהו קצת יותר יעיל? ואז עלה הרעיון של יצירת Exe יחיד שיעשה הכל: יוריד ויתקין את דוסבוקס, יאתר את Go.bat ויתחיל את המשחק. אבל, זה פתרון בעייתי מהסיבות שראינו כבר (אנטיוירוס וכו'). אז צמצמתי אותו: קובץ אצווה שיעשה חלק מהדברים (יתחיל את המשחק עם Go.bat), וידרוש מהמשתמש לעשות חלק אחר (להוריד ולהתקין את דוסבוקס). איך זה שונה מהפתרון שיש לנו עכשיו? ובכן, זה מאוד דומה, אבל ההבדל העיקרי הוא שלפי הפתרון החדש דוסבוקס יהיה מותקן רק פעם אחת, בעוד שלפי הפתרון הישן, יהיה עותק של דוסבוקס על כל משחק. בנוסף, קובץ האצווה החדש יכול להיות קצת יותר משוכלל: למשל, אם הוא לא מוצא התקנה של דוסבוקס, הוא יכול לפתוח את הדפדפן על עמוד ההורדה של דוסבוקס (או על המדריך שלנו).

וכך, נציב את הקישור אל החבילה החדשה בדף הורדת המשחק, ונאמר לגולשים: "הסתבכתם עם הפעלת המשחק? ראשית, התקינו דוסבוקס. שנית, קחו את הקובץ הזה ופרסו אותו לתיקיית המשחק. שלישית, הפעילו את הקובץ". זה מאוד דומה למה שיש היום אבל הרבה יותר יעיל וחסכוני.
והבונוס: במקרה כזה, אנחנו יכולים להתקדם בעתיד לחזון ה"חבילות מותאמות אישית" בצורה קלה וחסכונית יותר - כאשר נקבץ יחד עם קובץ האצווה גם קובץ conf מותאם שישמש להפעלת המשחק.

נשמע הגיוני? מובן?

בעניין ה"חבילה", נראה לי שאני כבר לא מצליח להבין מה קורה פה. מה שנראה שמתגבש כאן הוא בכלל לא "חבילה", אלא קובץ אצווה חדש שיחליף את ה-go.bat שקיים שם (או שיהיה לצידו) כחלק מההורדה הבסיסית.

לא התכוונתי לצרף להורדה של כל משחק גם את קובץ האצווה החדש. התכוונתי להציע את החבילה החדשה להורדה הישר מדף הורדת המשחק, כאשר החבילה הזו מכילה קובץ אצווה (חדש) שיידע להפעיל את המשחק ואולי גם קובץ conf מותאם למשחק הספציפי שמורידים. יהיה צריך לפרוס את החבילה הזו לתוך התיקייה שאליה נפרס המשחק.

אוקיי, אז תיאלץ לחכות לתשובה מגורדי.

אני לא זוכר מה בדיוק הסיפור. אני מנחש שלקחתי את הלוגו של האתר, התאמתי למידות של האשף ושמרתי כ-BMP.

[Radioactive Grandpa]

אוקי, חשבתי שזו עשויה להיות הכוונה, אבל נשמע לי מוזר לקחת קובץ אצוה פשוט וקטנטן (גם אם נורא מתוחכם) ולקרוא לו "חבילה" ולהציע אותו לבדו להורדה.
זה מוזר אבל הרעיון נראה לי טוב (רק, אם הוא מפעיל דפדפן, שישאל קודם את המשתמש. "תכנת דוסבוקס אינה מותקנת בתיקיית ברירת המחדל. כדי להפעיל את המשחק באמצעות תכנית זאת עליך להוריד ולהתקין את דוסבוקס, או להעביר את תיקיית ההתקנה למיקום ברירת המחדל. האם ברצונך להוריד את דוסבוקס כעת?")

והבונוס: במקרה כזה, אנחנו יכולים להתקדם בעתיד לחזון ה"חבילות מותאמות אישית" בצורה קלה וחסכונית יותר - כאשר נקבץ יחד עם קובץ האצווה גם קובץ conf מותאם שישמש להפעלת המשחק.

למעשה, אפשר לצרף את ה-conf לתיקיית ההורדה, וכך הוא יוכל להיות, מבחינה עקרונית, הכי מותאם שאפשר. ולמה בעצם לא לכלול את קובץ האצוה בהורדה, אם זה כולה קובץ אצוה? (go1.bat ו-go2.bat. בכל המקומות שבהם האתר מתייחס לקובץ go.bat לשם הפעלת המשחק, אפשר לציין את שתי האפשרויות: הפעלה עצמאית והפעלה אוטומטית של דוסבוקס.)

אני לא זוכר מה בדיוק הסיפור. אני מנחש שלקחתי את הלוגו של האתר, התאמתי למידות של האשף ושמרתי כ-BMP.

זה בהחלט לא נראה ככה. היתה כאן שמירה כ-jpg או משהו כזה בדרך לדעתי. לא שיש טעם להתעכב על זה... אם רק אני שם לב לזה, עזבו. בכל מקרה, הנה גרסה נקיה שמבוססת על העימוד שעוג הציע, בגודל הדרוש (אך ללא מתיחה, ה"אובייקטים הגראפיים" בגודלם המקורי. הפער כל-כך קטן שאני לא רואה צורך למתוח את זה בכלל ולפגוע במקור).

אמרו חז"ל: "צרת רבים - חצי נחמה" אז אני לא מתבייש בזה שאני שמח לראות שאני לא היחיד שמזדקן.

טוב, חז"ל גם אמרו שכולם יודעים שסבא רדיואקטיבי מזדקן בקצב מעריכי.
והם גם ספרו לי שעדיף לי להודות בזה מלהציג את התירוצים שיש לי לגבי המקרה הזה.

[brother34]

אני מתנצל מראש אם אני נכנס פה באמצע, ואם זה לא המקום - עדיין לא כל כך ברור לי מה הגדרות השרשור הזה, ולא ידעתי איפה עוד לשים את זה
בקיצר : ABUSE הסכים לעבוד בדוסבוקס רק אחרי שהגדרתי לו שהמשחק נמצא על כונן C (בכתיבת הפקודה MOUNT וכו').
זה משהו שצריך לציין בפני מורידי המשחק העתידיים? (אני בדרך כלל לא מגדיר בMOUNT ככונן C, סתם כי אני רגיל שזה הכונן ה"חשוב".)

[Radioactive Grandpa]

כן, זה שווה ציון. רק שני דברים:
1. יש סיכוי לא רע שמי שיהיה מספיק מתוחכם/עצמאי כדי להרכיב נתיב כלשהו ככונן קשיח שאינו מכונֶה C (כלומר, גם לא עושה שימוש בשיטת הגרירה, וגם לא פועל לפי התיאור במדריך אצלנו), ידע לזהות את הבעיה ולפעול בהתאם (ההודעה הרי מתקבלת במפורש, זה לא שצריך ניסוי וטעיה כדי להבין שהמשחק צריך כונן C).
2. למעשה, התיקייה לא צריכה להיות בכונן C. צריך להיות כונן C. כלומר, אתה יכול להרכיב שקרכלשהו כ-C ואת תיקיית המשחק או אחת מהמכילות אותה ככונן אחר, והמשחק יעבוד.

נראה לי שאנסח איזה ערך בשאילתא שמציע להפעיל את המשחק באמצעות דוסבוקס, והמידע הזה יצוין ע"י הערה.

אגב,

אני בדרך כלל לא מגדיר בMOUNT ככונן C, סתם כי אני רגיל שזה הכונן ה"חשוב".

אל תשכח שזה כונן מדומה, והסביבה המדומה היא מציאות קצת שונה. Abuse הוא לא המשחק היחיד שעושה בעיות כשלא מרכיבים כונן C בדוסבוקס. אני חושב שבתחילת שנות התשעים המצב הנפוץ היה שכונן C הוא הכונן הקשיח היחיד, ו-D ייצג בד"כ את כונן ה-CD-ROM. ככה אני רגיל להגדיר בד"כ את הכוננים המדומים בדוסבוקס.

[Gordi]

נראה לי שאנסח איזה ערך בשאילתא שמציע להפעיל את המשחק באמצעות דוסבוקס, והמידע הזה יצוין ע"י הערה.

הנה גרסה נקיה שמבוססת על העימוד שעוג הציע

תודה ותודה!

נשמע לי מוזר לקחת קובץ אצוה פשוט וקטנטן (גם אם נורא מתוחכם) ולקרוא לו "חבילה" ולהציע אותו לבדו להורדה.

תוסיף לו קובץ conf וכבר יש שני קבצים

מעשה, אפשר לצרף את ה-conf לתיקיית ההורדה, וכך הוא יוכל להיות, מבחינה עקרונית, הכי מותאם שאפשר. ולמה בעצם לא לכלול את קובץ האצוה בהורדה, אם זה כולה קובץ אצוה? (go1.bat ו-go2.bat. בכל המקומות שבהם האתר מתייחס לקובץ go.bat לשם הפעלת המשחק, אפשר לציין את שתי האפשרויות: הפעלה עצמאית והפעלה אוטומטית של דוסבוקס.)

אני מתנגד לפתרון הזה כי:
1. יש לנו כבר כמעט 1000 משחקים בלי ה"חבילה" כלולה בהורדה, ואני בטח לא מתכוון לעבור על כולם ולכלול בהם את החבילה.
2. יותר חשוב: לא הייתי רוצה לאבד את היכולת לעדכן/לתקן את קבצי החבילה בקלות. אם הם יהיו כלולים בתוך כל הורדה, זה יהיה סיוט.

אז ניסיתי לקחת את התבנית של Og צעד אחד קדימה, והנה מה שיצא לי:

[left]@ECHO OFF

:: ######################################################################
:: # Old-Games.Org DOSBox Game Launcher                                 #
:: # ----------------------------------                                 #
:: #                                                                    #
:: # Usage: After installing DOSBox in the default location,            #
:: # place this file in the same directory as the Go.Bat file           #
:: # and run this file. This file will then try to run Go.bat           #
:: # using DOSBox.                                                      #
:: #                                                                    #
:: # If a *.conf file named "MasaDBL.conf" exists in the                #
:: # same directory, it will be used as the DOSBox conf file.           #
:: #                                                                    #
:: # If an argument is supplied to this script, it will be              #
:: # used instead of the default "Go.bat" file.                         #
:: #                                                                    #
:: # DOSBox is an open-source DOS emulator.                             #
:: # More details can be found at: http://www.dosbox.com/" target="_blank               #
:: #                                                                    #
:: # For questions and comments, please visit our forum:                #
:: #   http://www.old-games.org/f" target="_blank                                       #
:: #                                                                    #
:: ######################################################################

:: THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, 
:: EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES 
:: OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND 
:: NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS 
:: BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN 
:: ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN 
:: CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE 
:: SOFTWARE. 

:: ==========================================================================

:: Set this to 1 in order to view debug printouts
SET DEBUG=0

IF "%DEBUG%"=="1" GOTO :SET_DEBUG
GOTO :SET_RELEASE

:SET_DEBUG
SET PrintDebug=ECHO - 
SET ExecDebug=
GOTO :START

:SET_RELEASE
SET PrintDebug=::
SET ExecDebug=::
GOTO :START


:START
SET DOSBoxDownloadPage="http://sourceforge.net/projects/dosbox/ ... t/download"
SET LAUNCH_FILENAME=Go.bat
SET DOSBOX_EXEC=DOSBox.exe
SET DOSBOX_PARAMS= -exit -noconsole
SET DOSBOX_LATEST=DOSBox-0.74
SET APP_NAME=MasaDBL

SET CONF_FILENAME=%APP_NAME%.conf
SET CACHE_FILENAME=%APP_NAME%_Cache.txt

:: Header

ECHO.
ECHO  ___ _   _    ____				  
ECHO / _ \^| ^| __^| ^|   / ___^| __ _ _ __ ___  ___ ___    ___ _ __ __ _ 
ECHO ^| ^| ^| ^| ^|/ _` ^|_____^| ^| _ / _` ^| '_ ` _ \ / _ \/ __^|   / _ \^| '__/ _` ^|
ECHO ^| ^|_^| ^| ^| (_^| ^|_____^| ^|_^| ^| (_^| ^| ^| ^| ^| ^| ^| __/\__ \  ^| (_) ^| ^| ^| (_^| ^|
ECHO \___/^|_^|\__,_^|   \____^|\__,_^|_^| ^|_^| ^|_^|\___^|^|___/ (_) \___/^|_^| \__, ^|
ECHO							^|___/ 
ECHO.
ECHO.

ECHO	  --===== Old-Games.Org DOSBox Launcher v0.1 =====--
ECHO.
ECHO.

:: This is the file we will try to launch with DOSBox
SET LAUNCH_PATH="%CD%\%LAUNCH_FILENAME%"

:: If an argument is supplied, use it as the file to launch (instead of the default "Go.bat")
IF NOT "%1"=="" (
 IF EXIST "%1" (
   %PrintDebug% Overwriting default launch path with: %1
   SET LAUNCH_PATH="%1"
 )
)

%PrintDebug% Launch path is: %LAUNCH_PATH%


:: Try to locate DOSBox


:: First, try to read the path to DOSBox from the cache:
%PrintDebug% Trying to read DOSBox path from cache
IF EXIST "%USERPROFILE%\Local Settings\Application Data" ( 
 SET CACHE_PATH="%USERPROFILE%\Local Settings\Application Data\%APP_NAME%\%CACHE_FILENAME%"
 mkdir "%USERPROFILE%\Local Settings\Application Data\%APP_NAME%\" > NUL 2>&1 
)
IF EXIST "%LOCALAPPDATA%" ( 
 SET CACHE_PATH="%LOCALAPPDATA%\%APP_NAME%\%CACHE_FILENAME%"
 mkdir "%LOCALAPPDATA%\%APP_NAME%\" > NUL 2>&1 
)

IF NOT EXIST %CACHE_PATH% GOTO :DOSBOX_TRY_DEFAULT_PATH


%PrintDebug% Cache path is: %CACHE_PATH%

:: We found a cached file, try to read from cache:
SET /p DOSBOX_CACHED_PATH=<%CACHE_PATH%
%PrintDebug% DOSBOX_CACHED_PATH path is: %DOSBOX_CACHED_PATH%
IF NOT EXIST %DOSBOX_CACHED_PATH% GOTO :DOSBOX_TRY_DEFAULT_PATH

%PrintDebug% Cached path exists!

SET DOSBoxPath=%DOSBOX_CACHED_PATH%
GOTO :FOUND_DOSBOX

OSBOX_TRY_DEFAULT_PATH
:: Can't find DOSBox using cache, make an educated guess using the default location of the latest installation
SET DOSBoxPath="%programfiles%\%DOSBOX_LATEST%\%DOSBOX_EXEC%"
%PrintDebug% Trying to use predefined DOSBox path: %DOSBoxPath%

IF EXIST %DOSBoxPath% (
 %PrintDebug% Using predefined DOSBox path
 GOTO :FOUND_DOSBOX
)

%PrintDebug% Can't find DOSBox in predefined path
GOTO :DOSBOX_SEARCH

OSBOX_SEARCH
:: If we can't find DOSBox in the default location, try locating it in the ProgramFiles directory
%PrintDebug% Searching for a DOSBox executable in %programfiles%:

ECHO Searching for DOSBox...
:: If multiple entries are found, the final path should be the last (thus, latest) one
FOR /f "delims=" %%a IN ('dir /B /S "%programfiles%\""*%DOSBOX_EXEC%*"') DO (
 %PrintDebug% Found a DOSBox executable at: %%a
 SET DOSBoxPath="%%a"
)

IF EXIST %DOSBoxPath% GOTO :FOUND_DOSBOX
GOTO :CANT_FIND_DOSBOX

:CANT_FIND_DOSBOX
ECHO.
ECHO ERROR: Can't find DOSBox!
ECHO You need to install DOSBox in order to use this program.
GOTO :TO_INSTALL_DOSBOX

:TO_INSTALL_DOSBOX
ECHO.
SET /P InstallDosbox=Would you like to open the DOSBox download page [Y or N]? 
IF "%InstallDosbox%" == "Y" GOTO :LAUNCH_BROWSER
IF "%InstallDosbox%" == "y" GOTO :LAUNCH_BROWSER

IF "%InstallDosbox%" == "N" GOTO :DONT_LAUNCH_BROWSER
IF "%InstallDosbox%" == "n" GOTO :DONT_LAUNCH_BROWSER
GOTO :TO_INSTALL_DOSBOX

:LAUNCH_BROWSER
ECHO Launching Browser
%PrintDebug% DOSBox download page is: %DOSBoxDownloadPage%
START "" %DOSBoxDownloadPage% 
ECHO Please Install DOSBox (using default options) and retry...
GOTO :END_BAD

ONT_LAUNCH_BROWSER
ECHO Please Install DOSBox (using default options) and retry...
GOTO :END_BAD

:FOUND_DOSBOX
%PrintDebug% Final DOSBox path set to: %DOSBoxPath%

::Cache DOSBox path for the future
IF NOT [%CACHE_PATH%] == [] (
 
 ECHO %DOSBoxPath% > %CACHE_PATH% 2>NUL
)

:: Now try to locate Go.Bat:
IF EXIST %LAUNCH_PATH% GOTO :FOUND_GO
GOTO :CANT_FIND_GO

:FOUND_GO
%PrintDebug% Found %LAUNCH_PATH%, launching game!

SET CONF_PARAM=
IF EXIST %CONF_FILENAME% (
 %PrintDebug% Using *.conf file: %CONF_FILENAME%
 SET CONF_PARAM= -conf "%CD%\%CONF_FILENAME%" 
)
SET DOSBOX_COMMAND=%DOSBoxPath% %LAUNCH_PATH% %DOSBOX_PARAMS% %CONF_PARAM%
CALL :FILE_DIR_FROM_PATH DOSBOX_DIR %DOSBoxPath%
%PrintDebug% DOSBox directory is: %DOSBOX_DIR%
IF "%DOSBOX_DIR%"=="" GOTO :INTERNAL_ERROR
SET DOSBOX_DIR="%DOSBOX_DIR%"
IF NOT EXIST %DOSBOX_DIR% GOTO :INTERNAL_ERROR
%PrintDebug% Starting the following command: %DOSBOX_COMMAND%
::ECHO Launching game!
CALL :PRINT_SUCCESS
TIMEOUT 2 > NUL
START "" /D%DOSBOX_DIR% /B %DOSBOX_COMMAND%
GOTO :END_GOOD

:CANT_FIND_GO
ECHO.
ECHO ERROR: Can't find "%LAUNCH_FILENAME%" in the current directory!
ECHO Are you sure you have extracted this program to the correct directory?
ECHO.
ECHO Please move this program to the correct directory 
ECHO  (the one containing %LAUNCH_FILENAME%) and try again...
GOTO :END_BAD

:: Given a full path to a file, extract the folder which contains the file and save it as %<resultVar>%
:FILE_DIR_FROM_PATH <resultVar> <pathVar>
(
 SET "%~1=%~dp2"
 EXIT /b
)

:PRINT_SUCCESS (
SET ECHO_WIDTH=ECHO		
%ECHO_WIDTH%       /\          /\          /\
%ECHO_WIDTH%  /\//\\/\    /\//\\/\    /\//\\/\
%ECHO_WIDTH% /\//\\\///\\/\//\\\///\\/\//\\\///\\/\
%ECHO_WIDTH%//\\\//\/\\///\\\//\/\\///\\\//\/\\///\\
%ECHO_WIDTH%\\//\/                            \/\\//
%ECHO_WIDTH% \/            Launching             \/
%ECHO_WIDTH% /\              Game!               /\
%ECHO_WIDTH%//\\/\                            /\//\\
%ECHO_WIDTH%\\///\\/\//\\\///\\/\//\\\///\\/\//\\\//
%ECHO_WIDTH% \/\\///\\\//\/\\///\\\//\/\\///\\\//\/
%ECHO_WIDTH%  \/\\//\/    \/\\//\/    \/\\//\/
%ECHO_WIDTH%       \/          \/          \/
EXIT /B
)

:INTERNAL_ERROR
ECHO ERROR: Internal Error
GOTO :END_BAD

:END_BAD
::COLOR C
ECHO.
ECHO For questions and comments, please visit our forum at:
ECHO   http://www.old-games.org/f
ECHO.
PAUSE
EXIT /B 1

:END_GOOD
%ExecDebug% PAUSE
EXIT[/left]

אני מקווה שזה לא Overkill וששום דבר לא התקלקל בצביעת התחביר ובמעבר ל-BB-Code.
בכל מקרה, אפשר למצוא פה גרסה נקייה להורדה.

מישהו מוכן להוריד ולנסות? הפעם לא צריך ללפות את השולחן באימה

[Radioactive Grandpa]

Holy cow. מדהים. והממזר הקטן מצא לי את דוסבוקס אפילו אחרי ששיניתי את שם התיקייה. יפה מאוד.

אחרי מפעל כזה כבר אי אפשר להתווכח על הדרך...

[brother34]

מייצג את המשתמש האהבל : עובד.